[量化交易]文华赢智t8模型 三指标共振日内策略
策略说明
该策略用于文华财经WT8软件。默认5分钟周期，如果用于其他周期，可以自行调整日内平仓时间。
注意：本模型源码用于文华财经赢智WH8软件。
策略源码
//均线定义变
MA1: EMA(C,5);
MA2: EMA(C,10);
MA3: EMA(C,20);
MA4: EMA(C,120);
//MACD定义变量
DIFF:= EMA(CLOSE,12)-EMA(CLOSE,26);
DEA := EMA(DIFF,9);
MACD:= 2*(DIFF-DEA);
//KD定义变量
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
KD金叉:=CROSS(K,D);
KD死叉:=CROSS(D,K);
LHD1:= MA1>MA2 && MA2>MA3 && MA3>MA4;//均线多头排列
LHD2:= CROSS (DIFF,DEA);//MACD金叉
LHD3:= CROSS (K,D);//KD金叉
LHK1:= MA1<MA2 && MA2<MA3 && MA3<MA4;//均线空头排列
LHK2:= CROSS (DEA,DIFF);//MACD死叉
LHK3:= CROSS (D,K);//KD死叉
DDW1:= LHD2 && LHD3;//MACD和RSV金叉共振,做多
DDW2:= LHD1 && LHD2;//均线多头且MACD金叉,做多
KKW1:= LHK2 && LHK3;//MACD和RSV死叉共振,做空
KKW2:= LHK2 && EXIST(LHK3,10);//MACD死叉且10日内存在KD死叉,做空
//风险率的定义与变量
RISK:= MONEYTOT<=INITMONEY*(1-10/100);//风控条件：本金风险率超过10%
//做多策略
(DDW1 || DDW2) && (TIME>=2100 || TIME<1455),BK;
LHK2 || LHK3,BP;//MACD死叉或KD死叉,平多仓
CLOSE<=(BKPRICE-20*MINPRICE),BP;//止损,亏损20个最小变动价位全部平仓
CLOSE<=BKHIGH*(1-8/100),BP;//止损,高点回撤8%,全部平仓
CLOSEMINUTE<=5,BP;//闭市前全部平仓,其他周期需要调整时间。
RISK,BP; //达到风控条件，模型清仓且不再开仓
//做空策略
(KKW1 || KKW2) && (TIME>=2100||TIME<1445),SK;
LHD2 || LHD3,SP;//MACD金叉或KD金叉,平空仓
CLOSE>=(SKPRICE-20*MINPRICE),SP;//止损,亏损20个最小变动价位全部平仓
CLOSE>=SKLOW*(1+8/100),SP;//止损,低点回撤8%,全部平仓
CLOSEMINUTE<=5,SP;//闭市前全部平仓
RISK,SP; //达到风控条件，模型清仓且不再开仓
QYHC:=HHV(MONEYTOT,0);
IDLE((MONEYTOT<QYHC*0.95 && MONEYTOT>QYHC*0.92) || MONEYTOT<QYHC*0.85);//权益回撤一定幅度停止交易
SETSIGPRICETYPE(BPK,LIMIT_ORDER);
SETSIGPRICETYPE(SPK,LIMIT_ORDER);
SETSIGPRICETYPE(BK,LIMIT_ORDER);
SETSIGPRICETYPE(SK,LIMIT_ORDER);
SETSIGPRICETYPE(BP,LIMIT_ORDER);
SETSIGPRICETYPE(SP,LIMIT_ORDER);
AUTOFILTER;
